易语言调用whois实现域名批量查询与注册的代码

.版本 2
.支持库 EThread
.程序集 窗口程序集_启动窗口
.子程序 _批量查询_被单击
启动线程 (&查询是否可以注册, , )
.子程序 查询是否可以注册
.局部变量 xml, 文本型
.局部变量 域名数组, 文本型, , "0"
.局部变量 计次, 整数型
批量查询.禁止 ＝ 真
批量查询.标题 ＝ “正在查询...”
域名数组 ＝ 分割文本 (删首尾空 (批量域名.内容), #换行符, )
结果.内容 ＝ “”
可以注册.内容 ＝ “”
.计次循环首 (取数组成员数 (域名数组), 计次)
  xml ＝ 到文本 (网页_访问 (“http://panda.www.net.cn/cgi-bin/check.cgi?area_domain=” ＋ 域名数组 [计次], , , , , , , , , ))
  .如果 (文本_取出中间文本 (xml, “<returncode>”, “<”, , ) ≠ “200”)
    结果.加入文本 (域名数组 [计次] ＋ “ ---查询失败” ＋ #换行符)
  .否则
    .如果真 (文本_取出中间文本 (xml, “<original>”, “ :”, , ) ＝ “210”)
      结果.加入文本 (域名数组 [计次] ＋ “ ---可以注册” ＋ #换行符)
      可以注册.加入文本 (域名数组 [计次] ＋ #换行符)
    .如果真结束
    .如果真 (文本_取出中间文本 (xml, “<original>”, “ :”, , ) ＝ “211”)
      结果.加入文本 (域名数组 [计次] ＋ “ ---已经注册” ＋ #换行符)
    .如果真结束
    .如果真 (文本_取出中间文本 (xml, “<original>”, “ :”, , ) ＝ “212”)
      结果.加入文本 (域名数组 [计次] ＋ “ ---域名格式错误” ＋ #换行符)
    .如果真结束
    .如果真 (文本_取出中间文本 (xml, “<original>”, “ :”, , ) ＝ “213 ”)
      结果.加入文本 (域名数组 [计次] ＋ “ ---查询超时” ＋ #换行符)
    .如果真结束
  .如果结束
  处理事件 ()
.计次循环尾 ()
批量查询.禁止 ＝ 假
批量查询.标题 ＝ “批量查询 域名是否可以注册”
.子程序 _whois查询_被单击
启动线程 (&查询whois, , )
.子程序 查询whois
.局部变量 html, 文本型
.局部变量 正则, 正则表达式类
.局部变量 计次, 整数型
.局部变量 text, 文本型
.局部变量 源码, 文本型
源码 ＝ 编码_utf8到gb2312 (到文本 (网页_访问 (“https://whois.22.cn/” ＋ 域名.内容, , , , , , , , , )))
html ＝ 文本_取出中间文本 (源码, “</em></li>”, “</ul>”, , )
whois结果.内容 ＝ “”
正则.创建 (“<span>(.*?)</span>(.*?)<”, html, , , , )
.计次循环首 (正则.取匹配数量 (), 计次)
  text ＝ text ＋ 正则.取子匹配文本 (计次, 1, ) ＋ “：” ＋ 正则.取子匹配文本 (计次, 2, ) ＋ #换行符
  处理事件 ()
.计次循环尾 ()
whois结果.内容 ＝ text
查询原始whois (源码)
.子程序 查询原始whois
.参数 源码, 文本型
.局部变量 正则, 正则表达式类
.局部变量 计次, 整数型
.局部变量 text, 文本型
.局部变量 html, 文本型
html ＝ 文本_取出中间文本 (源码, “whoisInfo” ＋ #引号 ＋ “>”, “</div>”, , )
正则.创建 (“(.*?)<br />”, 子文本替换 (html, “            ”, “”, , , 真), , , , )
.计次循环首 (正则.取匹配数量 (), 计次)
  text ＝ text ＋ 正则.取子匹配文本 (计次, 1, ) ＋ #换行符
  处理事件 ()
.计次循环尾 ()
whois原始内容.内容 ＝ text