易语言通过模拟的方式实现对微信的视频图片消息发送的代码

.版本 2
.支持库 spec
.支持库 internet
.程序集 程序集1
.子程序 _启动子程序, 整数型, , 请在本子程序中放置动态链接库初始化代码
_临时子程序 ()
返回 (0)
.子程序 _临时子程序
.局部变量 handle, 整数型, , "0"
.局部变量 i, 整数型
' 本名称子程序用作测试程序用，仅在开发及调试环境中有效，编译发布程序前将被系统自动清空，请将所有用作测试的临时代码放在本子程序中。 注意不要修改本子程序的名称、参数及返回值类型。
窗口_模糊遍历窗口 (, “ChatWnd”, , handle)
' 请打开微信群 不要合并
.计次循环首 (取数组成员数 (handle), i)
  调试输出 (窗口_取标题 (handle [i]))
  sendfile (窗口_取标题 (handle [i]), “C:\Documents and Settings\Administrator\桌面\2.mp4”) ' 视频
  sendimg (窗口_取标题 (handle [i]), “C:\Documents and Settings\Administrator\桌面\1.jpg”) ' 图片
  sendtext (窗口_取标题 (handle [i]), “www.jb51.net”) ' 消息
.计次循环尾 ()
调试输出 (getwechatgroup ())
.子程序 sendfile, , 公开
.参数 name, 文本型
.参数 file, 文本型
.局部变量 a, 文本型, , "0"
.局部变量 handle, 整数型
.如果真 (文件是否存在 (file) ＝ 假)
  返回 ()
.如果真结束
handle ＝ 昵称取句柄 (name)
窗口_强制显示 (handle, 真)
鼠标_单击 (handle, 10, 580, 1)
加入成员 (a, file)
剪辑板_置文件 (a)
键盘_单击 (#Ctrl键, 1)
程序_延时 (1000)
键盘_消息 (handle, #V键, 5, 假)
键盘_单击 (#Ctrl键, 2)
程序_延时 (1000)
PostMessageA (handle, 256, #回车键, 0)
窗口_最小化 (handle)
.子程序 昵称取句柄, 整数型
.参数 name, 文本型
.局部变量 handle, 整数型, , "0"
.局部变量 i, 整数型
窗口_模糊遍历窗口 (, “ChatWnd”, , handle)
.计次循环首 (取数组成员数 (handle), i)
  .如果真 (窗口_取标题 (handle [i]) ＝ name)
    返回 (handle [i])
  .如果真结束
.计次循环尾 ()
返回 (0)
.子程序 sendimg, , 公开
.参数 name, 文本型
.参数 file, 文本型
.局部变量 handle, 整数型
.局部变量 img, 字节集
.如果真 (file ＝ “”)
  返回 ()
.如果真结束
.如果真 (寻找文本 (file, “http”, , 假) ＝ -1)
  .如果真 (文件是否存在 (file) ＝ 假)
    返回 ()
  .如果真结束
.如果真结束
handle ＝ 昵称取句柄 (name)
窗口_强制显示 (handle, 真)
鼠标_单击 (handle, 10, 580, 1)
.如果 (寻找文本 (file, “http”, , 假) ≠ -1)
  img ＝ HTTP读文件 (file)
.否则
  img ＝ 读入文件 (file)
.如果结束
剪辑板_置图片 (img)
键盘_单击 (#Ctrl键, 1)
程序_延时 (1000)
键盘_消息 (handle, #V键, 5, 假)
键盘_单击 (#Ctrl键, 2)
程序_延时 (1000)
PostMessageA (handle, 256, #回车键, 0)
窗口_最小化 (handle)
.子程序 sendtext, , 公开
.参数 name, 文本型
.参数 text, 文本型
.局部变量 handle, 整数型
.如果真 (text ＝ “”)
  返回 ()
.如果真结束
handle ＝ 昵称取句柄 (name)
窗口_强制显示 (handle, 真)
鼠标_单击 (handle, 10, 580, 1)
剪辑板_置文本 (text)
.判断循环首 (剪辑板_取文本 () ＝ “”)
  剪辑板_置文本 (text)
.判断循环尾 ()
键盘_单击 (#Ctrl键, 1)
程序_延时 (1000)
键盘_消息 (handle, #V键, 5, 假)
键盘_单击 (#Ctrl键, 2)
程序_延时 (1000)
PostMessageA (handle, 256, #回车键, 0)
窗口_最小化 (handle)
.子程序 getwechatgroup, 文本型, 公开
.局部变量 handle, 整数型, , "0"
.局部变量 title, 文本型
.局部变量 i, 整数型
窗口_模糊遍历窗口 (, “ChatWnd”, , handle)
.计次循环首 (取数组成员数 (handle), i)
  .判断开始 (title ＝ “”)
    title ＝ 窗口_取标题 (handle [i])
  .默认
    title ＝ title ＋ #换行符 ＋ 窗口_取标题 (handle [i])
  .判断结束
.计次循环尾 ()
.如果真 (title ＝ “”)
  信息框 (“未检测到群列表,如已登录 请打开微信群 不要合并”, 0 ＋ 64, , )
.如果真结束
返回 (title)
.子程序 version, 文本型, 公开
返回 (“666”)